int dot_total = 4000;
dot [] dot_array = new dot [dot_total];

color bg_color = 0x000000;

BImage bg;
int bgW, bgH, bgSx, bgSy;
int black_array [][] = new int [400*200][3];
String bg_name [] = {"bg_circle.gif","bg_triangle.gif","bg_rectangle.gif"};
color tcol_array [] = {0x0000FF,0xFFFF00,0xFF0000};
int b = 0; // current numbers of Images

void setup(){
  size(500,500);
  background(bg_color);
  bg_setting();
  bg_array_setting();
  init_dot();
}
void mouseReleased(){
  b++;
  b = b%3;
  k = 0;
  bg_setting();
  bg_array_setting();
  move_dot();
}
void bg_setting(){
  bg = loadImage(bg_name[b]);
  bgW = bg.width;
  bgH = bg.height;
  bgSx = (width-bgW)/2;
  bgSy = (height-bgH)/2;
}
int k = 0; //current numbers of black pixels
void bg_array_setting(){
  for(int i=0;i<bgW*bgH; i++){
    if(bg.pixels[i] != color(255,255,255)){
      black_array[k][0] = i%bgW + bgSx;
      black_array[k][1] = int(i/bgW) + bgSy;
      black_array[k][2] = bg.pixels[i];
      k++;
    }
  }
}

void init_dot(){
  for(int i=0; i<dot_total; i++){
    int rand = (int)random(k);
    dot_array[i] = new dot();
    dot_array[i].ox = black_array[rand][0];
    dot_array[i].oy = black_array[rand][1];

    dot_array[i].tx = dot_array[i].ox;
    dot_array[i].ty = dot_array[i].oy;
    dot_array[i].x = dot_array[i].ox;
    dot_array[i].y = dot_array[i].oy;

    //dot_array[i].tcol = black_array[rand][2]; // color from bg
    dot_array[i].tcol = tcol_array[b];
  }
}
void move_dot(){
  for(int i=0; i<dot_total; i++){
    int rand = (int)random(k);
    dot_array[i].ox = black_array[rand][0];
    dot_array[i].oy = black_array[rand][1];
    dot_array[i].tx = dot_array[i].ox;
    dot_array[i].ty = dot_array[i].oy;
    //dot_array[i].tcol = black_array[rand][2];  // color from bg
    dot_array[i].tcol = tcol_array[b];
  }
}

void loop(){
  background(bg_color);
  for(int i=0;i<dot_total; i++){
    dot_array[i].move();
  }
}

class dot{
  float ox,oy,tx,ty,x,y;
  float dx,dy,dist;
  float mdx,mdy,mdist;
  float mx,my;
  float damperX,damperY;
  color tcol,col;
  float tr,tg,tb,r,g,b;
  dot(){
    damperX = 5 + random(15);
    damperY = 5 + random(15);
    r=b=g=255;
  }
  void move(){
    //calculate distance from mouse cursor
    mdx = mouseX - x;
    mdy = mouseY - y;
    mdist = sqrt(sq(mdx)+sq(mdy));
    if(mdist<(20+random(20))){
      mx = mouseX - pmouseX;
      my = mouseY - pmouseY;
      tx = x + mx * (40-mdist)/10 + random(60)-30;
      ty = y + my * (40-mdist)/10 + random(60)-30;
      damperX = 5 + random(15);
      damperY = 5 + random(15);

      //change ox,oy randomly
      if(random(10)<1){
        int rand = (int)random(k);
        ox = black_array[rand][0];
        oy = black_array[rand][1];
        //col = black_array[rand][2]; // color from bg
      }

    }else
    if(abs(tx-x)<1+random(10) && abs(ty-y)<1+random(10)){
      tx = ox + random(20) - 10;
      ty = oy + random(20) - 10;
    }

    dx = tx-x;
    dy = ty-y;
    dist = sqrt(sq(dx)+sq(dy));
    x += dx/damperX;
    y += dy/damperY;

    color_me();
    draw_me();
  }
  void color_me(){
    tr = red(tcol);
    tg = green(tcol);
    tb = blue(tcol);
    if(abs(tr-r)>.1 || abs(tg-g)>.1 || abs(tb-b)>.1){
      r += (tr-r)/damperX;
      g += (tg-g)/damperX;
      b += (tb-b)/damperX;
      col = color(r,g,b);
    }
  }
  void draw_me(){
    noStroke();
    fill(col);
    rect(x,y,1,1);
  }
}